第二十七章. Ear 插件

要使用 Ear 的插件，请在构建脚本中包含以下语句：
To use the Ear plugin, include in your build script:

apply plugin: 'ear'

Ear 插件向project 中添加了以下任务。
The Ear plugin adds the following tasks to the project.

Ear 插件向基础插件所加入的 tasks 添加了以下的依赖。
The Ear plugin adds the following dependencies to tasks added by the base plugin.

Ear 插件添加了两个依赖配置： deploy和 earlib。所有在 deploy配置中的依赖项都放在 EAR 文件的根目录中，并且是 不可 传递的。所有在 earlib 配置的依赖都放在 EAR 文件的“lib”目录中，并且是 可 传递的。
The Ear plugin adds two dependency configurations: deploy and earlib . All dependencies in the deploy configuration are placed in the root of the EAR archive, and are not transitive. All dependencies in the earlib configuration are placed in the 'lib' directory in the EAR archive and are transitive.

这些属性由一个 EarPluginConvention 公约对象提供。
These properties are provided by a EarPluginConvention convention object.

Ear task 的默认行为是将 src/main/application的内容复制到archive 的根目录下。如果你的 application目录没有包含 META-INF/application.xml部署描述符，那么将会为你生成一个。
The default behavior of the Ear task is to copy the content of src/main/application to the root of the archive. If your application directory doesn't contain a META-INF/application.xml deployment descriptor then one will be generated for you.

另请参阅 Ear 。
Also have a look at Ear .

下面是一个示例，展示了最重要的自定义选项：
Here is an example with the most important customization options:

apply plugin: 'ear'
apply plugin: 'java'

repositories { mavenCentral() }

dependencies {
    //following dependencies will become the ear modules and placed in the ear root
    deploy project(':war')

    //following dependencies will become ear libs and placed in a dir configured via libDirName property
    earlib group: 'log4j', name: 'log4j', version: '1.2.15', ext: 'jar'
}

ear {
    appDirName 'src/main/app'  // use application metadata found in this folder
    libDirName 'APP-INF/lib'  // put dependency libraries into APP-INF/lib inside the generated EAR;
                                // also modify the generated deployment descriptor accordingly
    deploymentDescriptor {  // custom entries for application.xml:
//      fileName = "application.xml"  // same as the default value
//      version = "6"  // same as the default value
        applicationName = "customear"
        initializeInOrder = true
        displayName = "Custom Ear"  // defaults to project.name
        description = "My customized EAR for the Gradle documentation"  // defaults to project.description
//      libraryDirectory = "APP-INF/lib"  // not needed, because setting libDirName above did this for us
//      module("my.jar", "java")  // wouldn't deploy since my.jar isn't a deploy dependency
//      webModule("my.war", "/")  // wouldn't deploy since my.war isn't a deploy dependency
        securityRole "admin"
        securityRole "superadmin"
        withXml { provider -> // add a custom node to the XML
            provider.asNode().appendNode("data-source", "my/data/source")
        }
    }
}

你还可以使用 Ear 任务提供的自定义选项，如 from和 metaInf。
You can also use customization options that the Ear task provides, such as from and metaInf .

假设你已经有了 application.xml ，并且想要使用它而不是去配置 ear.deploymentDescriptor代码段。去把 META-INF/application.xml 放在你的源文件夹里的正确的位置（请查看 appDirName 属性）。这个已存在的文件的内容将会被使用，而 ear.deploymentDescriptor 里的显示配置则会被忽略。
Let's say you already have the application.xml and want to use it instead of configuring the ear.deploymentDescriptor section. To accommodate that place the META-INF/application.xml in the right place inside your source folders (see the appDirName property). The existing file contents will be used and the explicit configuration in the ear.deploymentDescriptor will be ignored.